; CUSeeMe Installer  1995 Robert Reiswig (rcr@netcom.com)
;
; Version 1.0 June 4, 1995
;  - Original version. Thank you very much Robert.
;
; Version 1.1 June 4, 1995
;  - Installer now creates a destination directory called "ACUSeeMe" in
;    the directory that the user chooses
;  - Changed the variable name "CUDir" to "InstallDir"
;  - Changed ACUSeeMeVer to "1.50"
;  - Minor cosmetic changes
;
; Version 1.2 July 6, 1995
;  - Changed ACUSeeMeVer to "2.00"
;  - Changed the message from "The installer will create a drawer there."
;    to "The installer will create a drawer there or install into the
;    existing ACUSeeMe directory."
;  - Since ACUSeeMe now actually uses the reflectors.txt file, the user
;    is given the option to install it.
;

;********************************************************************
; Current Version of ACUSeeMe
;********************************************************************
(set ACUSeeMeVer "2.01") 


;********************************************************************
; Info on ACUSeeMe and Installer Man
;********************************************************************
(message "\n\nACUSeeMe V" ACUSeeMeVer "\n\n"
         "Network video-conferencing tool\n\n"
         "by\n\nBerend Ozceri\n(bo24@andrew.cmu.edu)\n\n"
         "Original CUSeeMe  1994, 1995 Cornell University\n"
         "Amiga CUSeeMe  1994, 1995 Berend Ozceri"
)


;********************************************************************
; Ask where to put it
;********************************************************************
(set InstallDir
  (askdir 
    (prompt "Please select where you wish to install\nACUSeeMe V"ACUSeeMeVer"\n"
            "(The installer will create a drawer there or install into the existing ACUSeeMe directory.)")
    (help   "Please select where you wish to install ACUSeeMe. A directory "
            "called ACUSeeMe (and an icon for it) will be created in the "
            "directory selected.")
    (default "Work:")
  )
)
(set InstallDir (tackon InstallDir "ACUSeeMe"))
(makedir InstallDir)
(set @default-dest InstallDir)


;********************************************************************
; Double Check on the CPU, to make sure
;********************************************************************
(set cpu (database "cpu"))
(if (= cpu 68000) (set #cpu 0))
(if (= cpu 68010) (set #cpu 1))
(if (= cpu 68020) (set #cpu 2))
(if (= cpu 68030) (set #cpu 3))
(if (= cpu 68040) (set #cpu 4))

(if (> (exists ("libs:68060.library")) 0) (set #cpu 5))

(set #cpu
  (askchoice 
    (choices "68000" "68010" "68020" "68030" "68040" "68060")
	  (prompt "Central Processing Unit Check")
	  (help   "The ACUSeeMe binary comes in two versions; one for Amigas with "
            "68000 or 68010 CPUs and one for Amigas with 68020, 68030, 68040 "
            "or 68060 CPUs. Please choose the CPU type of your Amiga. The "
            "correct binary will then be installed.")
    (default #cpu)
	)
)


;********************************************************************
; Check for old version
;********************************************************************
(if (> (exists (cat InstallDir "ACUSeeMe")) 0)
   (rename (cat InstallDir "ACUSeeMe") (cat InstallDir "ACUSeeMe_old")) 
)

(if (> (exists (cat InstallDir "ACUSeeMe.info")) 0)
   (rename (cat InstallDir "ACUSeeMe.info") (cat InstallDir "ACUSeeMe_old.info")) 
)


;********************************************************************
; Copy Correct file 
;********************************************************************
(if (< #cpu 2) (copyfiles (source "ACUSeeMe_000") (dest InstallDir) (newname "ACUSeeMe") (infos)))
(if (> #cpu 1) (copyfiles (source "ACUSeeMe_020") (dest InstallDir) (newname "ACUSeeMe") (infos)))


;********************************************************************
; Copy reflectors.txt if user wants it
;********************************************************************
(set #wants-reflectors
  (askbool
	  (prompt "ACUSeeMe can read reflector aliases (i.e. a reflector name "
						"and IP address pair) from the \"Reflectors.txt\" file and "
						"present the user with a list of reflectors in the connect "
						"window. The supplied \"Reflectors.txt\" file is a somewhat "
						"up to date file of such aliases. Would you like to install "
            "the \"Reflectors.txt\" file? ")
		(help "")
		(default 0)
	)
)

(if #wants-reflectors (copyfiles (source "Reflectors.txt") (dest InstallDir) (infos)))
